masputih.com: Text2Bitmap

22 April 2008 in ActionScript 3, Demo | permalink

Text2Bitmap

Berikut ini contoh bagaimana membuat objek bitmap dari teks dinamis.

Document Class ( Main )

/**************************************************
created by Anggie Bratadinata | www.masputih.com
***************************************************/
package  {

import fl.controls.Button;
	import fl.controls.ColorPicker;
	import fl.controls.ComboBox;
	import fl.controls.TextInput;
	import fl.events.ColorPickerEvent;
	import flash.display.*;
	import flash.events.Event;
	import flash.events.FocusEvent;
	import flash.events.MouseEvent;
	import flash.events.TextEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import fl.data.DataProvider;

public class Main extends Sprite{
		
		//on-stage objects
		public var messageTxt:TextInput;
		public var updateBtn:Button;
		public var colorPicker:ColorPicker;
		public var blendModeCb:ComboBox;
		public var canvas:MovieClip;
		
		private var blendModes:Array = [
			{label:"NORMAL",data:BlendMode.NORMAL},
			{label:"ADD", data:BlendMode.ADD},
			{label:"ERASE", data:BlendMode.ERASE },
			{label:"DARKEN", data:BlendMode.DARKEN },
			{label:"DIFFERENCE", data:BlendMode.DIFFERENCE },
			{label:"HARDLIGHT", data:BlendMode.HARDLIGHT },
			{label:"INVERT", data:BlendMode.INVERT },
			{label:"LIGHTEN", data:BlendMode.LIGHTEN },
			{label:"MULTIPLY", data:BlendMode.MULTIPLY },
			{label:"OVERLAY", data:BlendMode.OVERLAY},
			{label:"SCREEN", data:BlendMode.SCREEN },
			{label:"SUBTRACT", data:BlendMode.SUBTRACT }
		];
		
		public function Main() {
			init();
		}
		
		private function init():void {
			
			canvas.blendMode = BlendMode.LAYER;
			
			messageTxt.text = "type something here ...";
			messageTxt.addEventListener(FocusEvent.FOCUS_IN, clearTextInput);
			messageTxt.addEventListener(Event.CHANGE, textInputListener);
			
			colorPicker.selectedColor = 0x000000;
			colorPicker.addEventListener(ColorPickerEvent.CHANGE, colorPickerListener);
			
			blendModeCb.dataProvider =  new DataProvider(blendModes);
			blendModeCb.selectedIndex = 0;
			blendModeCb.addEventListener(Event.CHANGE, comboBoxListener);
			
			updateBtn.enabled = false;
			updateBtn.addEventListener(MouseEvent.CLICK, buttonListener);
			
			renderText2Bitmap(messageTxt.text);
		}
		
		private function clearTextInput(e:FocusEvent):void {
			messageTxt.text = '';
		}
		
		private function textInputListener(e:Event):void {
			if (e.type == Event.CHANGE) {
				updateBtn.enabled = true;
			}
		}
		
		private function colorPickerListener(e:ColorPickerEvent):void {
			renderText2Bitmap(messageTxt.text);
		}
		
		private function comboBoxListener(e:Event):void {
			renderText2Bitmap(messageTxt.text);
		}
		
		private function buttonListener(e:MouseEvent):void {
			renderText2Bitmap(messageTxt.text);
		}
				
		private function renderText2Bitmap(text:String):void {
			var txtFormat:TextFormat = new TextFormat();
			txtFormat.font = "Verdana";
			txtFormat.color = colorPicker.selectedColor;
			txtFormat.size = 50;
			
			var dummyTxt:TextField = new TextField();
			dummyTxt.autoSize = TextFieldAutoSize.LEFT;
			dummyTxt.defaultTextFormat = txtFormat;
			dummyTxt.text = text;
			
			var bd:BitmapData = new BitmapData(dummyTxt.width, dummyTxt.height, true, 0x00000000);
			bd.draw(dummyTxt, null, null, null, null, true);
			
			var bm:Bitmap = new Bitmap(bd, "auto", true);
			bm.blendMode = blendModeCb.selectedItem.data;
			bm.width = canvas.width;
			bm.height = canvas.height;
			
			if (canvas.numChildren > 1) canvas.removeChildAt(1);
			canvas.addChildAt(bm,1);
			
			
		}
		
		
	}
	
}

Possibly related articles:

Next article:: Light3DExplorer v2
Previous article:: Membuat Image Uploader

Commenting is closed for this article.

masputih.com

Text2Bitmap

Document Class ( Main )

Possibly related articles:

Looking for something ?

Categories

Friends

Books I Read

Resources