masputih.com: Away3D + Flint Particle System

30 March 2008 in Away3D, Demo | permalink

Away3D + Flint Particle System

Hasil main-main dengan Flint Particle System dan Away3D. Kode utk Flint, saya kopi dari salah satu demo di website Flint.

Sourcecode

package  {

import away3d.cameras.*;
	import away3d.core.material.*;
	import away3d.core.render.*;
	import away3d.core.scene.*
	import away3d.objects.*;
	import away3d.core.math.*;

import flash.system.System;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	
	import org.flintparticles.actions.*;
	import org.flintparticles.counters.*;
	import org.flintparticles.displayObjects.Dot;
	import org.flintparticles.emitters.*;
	import org.flintparticles.initializers.*;
	import org.flintparticles.zones.*;  
	
	import flash.filters.BlurFilter;
	import flash.display.*;
	import flash.events.*;

public class Main extends Sprite {
		
		private var _view:View3D;
		private var _camera:HoverCamera3D;
		private var _scene:Scene3D;
		private var _renderer:BasicRenderer;
		
		private var _tf:TextField;
		
		public function Main() {
			
			initAway();
			initFlint();
			init3DObject();
			
			_tf = new TextField();
			_tf.x = stage.stageWidth/2 - _tf.width/2;
			_tf.y = stage.stageHeight - 50;
			_tf.autoSize = TextFieldAutoSize.CENTER;
			_tf.textColor = 0x666666;
			addChild(_tf);
			
			var info:TextField = new TextField();
			info.autoSize = TextFieldAutoSize.CENTER;
			info.x = stage.stageWidth/2 - info.width/2;
			info.y = _tf.y + 20;
			info.textColor = 0x666666;
			info.text = "Press and hold the spacebar to pause the sphere's rotation";
			addChild(info);
			
			stage.addEventListener(KeyboardEvent.KEY_DOWN, keyListener);
			stage.addEventListener(KeyboardEvent.KEY_UP, keyListener);
		}
		
		private function initAway():void{
			_camera = new HoverCamera3D({zoom:3, focus:200, distance:1000});
			_camera.tiltangle = 0;
            _camera.targettiltangle = 0;
            _camera.mintiltangle = -90;
            _camera.maxtiltangle = 90;
            _camera.yfactor = 1; 
			
			_scene = new Scene3D();
			_renderer = new BasicRenderer();
			
			_view = new View3D({camera:_camera,scene:_scene,renderer:_renderer});
			_view.x = 200;
			_view.y = 200;

addChild(_view);
			addEventListener(Event.ENTER_FRAME,enterFrameListener);
		}
		
		private var _my3DObject:Object3D;
		private function init3DObject():void { 
			_my3DObject = new Sphere({name:"My3DObject",radius:200,segmentsW:16,segmentsH:16,bothsides:true});
			Sphere(_my3DObject).material = new MovieMaterial(_flintEmitter,{interactive:true})
			_scene.addChild(_my3DObject);
	    }
	    
		private var _flintEmitter:MovieClip;
		private var _emitter:BitmapEmitter;
		private function initFlint():void {
			_flintEmitter = new MovieClip();
			_flintEmitter.graphics.beginFill(0x000000,0);
			_flintEmitter.graphics.drawRect(0, 0, 200, 200);
			_flintEmitter.graphics.endFill();

_emitter = new BitmapEmitter();
			_emitter.addFilter( new BlurFilter( 2, 2, 1 ) );
			_emitter.setCounter( new Blast( 30 ) );

_emitter.addInitializer( new SharedImage( new Dot( 2 ) ) );
			_emitter.addInitializer( new ColorInit( 0xFFFF00FF, 0xFF00FFFF ) );
			_emitter.addInitializer( new Position( new RectangleZone( 10, 10, 380, 380 ) ) );

_emitter.addAction( new MutualGravity( 10, 500, 3 ) );
			_emitter.addAction( new BoundingBox( 0, 0, 400, 400 ) );
			_emitter.addAction( new SpeedLimit( 150 ) );
			_emitter.addAction( new Move() );
		
			_flintEmitter.addChild(_emitter);
			_emitter.start( );

}
		
		//flags the cube's rotation
		private var isStopped:Boolean = false;
		private function rotateObject(disabled:Boolean,target:Object3D):void {
			var n:Number = (!disabled) ? 1 : 0;
			if (target) {
				with (target) {					
					yaw(n);roll(n);pitch(n);
				}
			}
		}
		
		private function enterFrameListener(e:Event):void {
			rotateObject(isStopped,_my3DObject);
			_camera.hover();
			_view.render();	
			
			var mem:Number = System.totalMemory / 1024;
			_tf.text = "Memory usage : " + mem.toString() +" KBytes";
		}
		
		private function keyListener(e:KeyboardEvent):void {
			
			if (e.charCode != 32) return;

if (e.type == KeyboardEvent.KEY_DOWN) {					
				isStopped = true;
			}else if(e.type == KeyboardEvent.KEY_UP){
				isStopped = false;
			}
			
		}
	}
	
}

masputih.com

Away3D + Flint Particle System

Sourcecode

Links

Possibly related articles:

Looking for something ?

Categories

Friends

Books I Read

Resources